TAB+0(¬
CR+0(chr(13)
LF+0(chr(10)
VTAB+0(chr(11)
CRLF+0(¶+chr(10)
CROPTEXT+2(?(length(•1)>•2,•1[1,•2-1]+"…",•1)
ZLOGGING+2(callwithin("_PanoramaLib","ZLOG","zlogging",•1,•2)
ZLOGGING+0(callwithin("_PanoramaLib","ZLOG","zlogging", info("proceduredatabase"),info("procedurename"))
DIVZERO+2(?(•2<>0,•1/•2,0)
DIVZEROERROR+2(?(•2<>0,•1/•2,error("Cannot divide by zero"))
ROUND+2((int((•1/•2)+0.5))*•2
ARCCOSH+1(log(•1+sqr(•1+1)*sqr(•1-1))
ARCSINH+1(log(•1+sqr(•1*•1+1))
ARCTANH+1(0.5*(log(1+•1)-log(1-•1))
VALIDNUMBER+1((not str(•1) regexmatch "nan|inf")
NAN+1(str(•1) regexmatch "nan|inf"
EXP+1(eulersconstant() ^ •1
COSH+1((exp(•1)+exp(-•1))/2
SINH+1((exp(•1)-exp(-•1))/2
TANH+1((exp(•1)-exp(-•1))/(exp(•1)+exp(-•1))
PV+5(-(•3*(1+•1*•5)*((1+•1)^•2-1)/•1+•4)/((1+•1)^•2)
PMT+5((•3-•4) * •1 * (1 + •1)^•2 / ((1 + •1)^•2 -1)
FV+5(-(•4*((1+•1)^•2)+•3*(1+•1*•5)*((1+•1)^•2-1)/•1)
EXTRACT+3(switch(•3,-1,?(•1="",0,arraysize(•1,•2)),0,"",array(•1,•3,•2))
SANDWICH+3(?(•2="","",•1+•2+•3)
STRIPTOALPHA+1(stripchar(•1,"AZaz")
STRIPTONUM+1(stripchar(•1,"09")
TAGDATA+4(array(array(regexarray(•1,regexliteral(•2)+"(.*?)"+regexliteral(•3),chr(1)+"1"+chr(1),chr(1)+"2"+chr(1)),•4,chr(1)+"1"+chr(1)),2,chr(1)+"2"+chr(1))
TAGCOUNT+3(extract(regexarray(•1,regexliteral(•2)+"(.+?)"+regexliteral(•3),chr(1)+"1"+chr(1)),chr(1)+"1"+chr(1),-1)
RAWTAGS+3(regexarray(•1,regexliteral(•2)+"(.+?)"+regexliteral(•3),chr(1)+"1"+chr(1))
TAGSTRIP+3(replacemultiple(•1,rawtags(•1,•2,•3),"",chr(1)+1+chr(1))
TAGARRAY+4(arrayfilter(  regexarray(•1,regexliteral(•2)+"(.+?)"+regexliteral(•3),•4,chr(1)+"2"+chr(1)),  •4,{array(import(),2,chr(1)+"2"+chr(1))})
TAGSTART+4(val(array(array(array(regexarray(•1,regexliteral(•2)+"(.+?)"+regexliteral(•3),chr(1)+"1"+chr(1),chr(1)+"2"+chr(1),0x01000001),•4,chr(1)+"1"+chr(1)),2,chr(1)+"2"+chr(1)),1,","))
TAGEND+4(val(array(array(array(regexarray(•1,regexliteral(•2)+"(.+?)"+regexliteral(•3),chr(1)+"1"+chr(1),chr(1)+"2"+chr(1),0x01000001),•4,chr(1)+"1"+chr(1)),2,chr(1)+"2"+chr(1)),2,","))
TAGNUMBER+4(ignore(0,cache(•4,"spot"))+int(val("0"+replace(arrayfilter(arrayfilter(regexarray(•1,regexliteral(•2)+"(.+?)"+regexliteral(•3),"/","-",0x01000001),"/",{array(import(),2,"-")}),"/",{?(val(array(import(),1,","))<=spot and val(array(import(),2,","))>=spot,str(seq()),"")}),"/","")))
TIMEINTERVAL+2(cache(•2-•1,"deltatime")+?(deltatime<0,86400,0)
TIMEDIFFERENCE+2(cache(cache(•2-•1,"deltatime")+?(deltatime<0,86400,0),"deltatime")+?(deltatime>43200,-86400,0)
APPLEDAYZERO+0(2416481
SUPERDATE+2(max(•1-appledayzero(),0)*86400+•2
REGULARDATE+1(int((?(•1<0,•1 and 0xFFFFFFFF,•1)) / 86400 )+appledayzero()
REGULARTIME+1(?(•1<0,•1 and 0xFFFFFFFF,•1) mod 86400
TIME24+1(?(•1<0,86400 - (-•1 mod 86400),•1 >= 86400, •1 mod 86400, •1)
TEXTSTUFF+3(?(•3+1 > length(•1), •1+rep(" ",•3-length(•1))+•2,•1[1,•3]+•2+•1[•3+1+length(•2),-1])
MONEY+1(pattern(•1,"#,.##")
DOLLARSANDCENTS+1(pattern(•1,"§ dollar~ and ¢¢ cents")
SCIENTIFICNOTATION+1(pattern(•1,"#.###E")
DATESTR+1(datepattern(•1,"mm/dd/yy")
LONGDATESTR+1(datepattern(•1,"Month ddnth, YYYY")
COMPLETEDATESTR+1(datepattern(•1,"DayOfWeek, Month ddnth, YYYY")
EURODATESTR+1(datepattern(•1,"dd-MON-yyyy")
DAYSTR+1(datepattern(•1,"DayOfWeek")
TIMESTR+1(upper(timepattern(•1,"hh:mm am/pm"))
LONGTIMESTR+1(upper(timepattern(•1,"hh:mm:ss am/pm"))
SUPERNOW+0(superdate(today(),now())
SUPERDATESTR+1(datepattern(regulardate(•1),"mm/dd/yy")+" "+upper(timepattern(regulartime(•1),"hh:mm am/pm"))
SUPERDATESECONDSSTR+1(datepattern(regulardate(•1),"mm/dd/yy")+" "+upper(timepattern(regulartime(•1),"hh:mm:ss am/pm"))
SUPERDATEPATTERN+3(?(•1=0,"",datepattern(regulardate(•1),•2)+upper(timepattern(regulartime(•1),•3)))
TEXTTIMEDIFFERENCE+2(timepattern(timedifference(time(•1),time(•2)),"hh:mm:ss")
TEXTTIMEINTERVAL+2(timepattern(timeinterval(time(•1),time(•2)),"hh:mm:ss")
HEX+1(radix("hex",•1)
HEXSTR+1(radixstr("hex",•1)
HEXBYTE+1(radixstr("hex",•1)[-2,-1]
HEXWORD+1(radixstr("hex",•1)[-4,-1]
HEXLONG+1(radixstr("hex",•1)[-8,-1]
RECTANGLESIZESTR+1(str(rtop(•1))+","+str(rleft(•1))+","+str(rheight(•1))+","+str(rwidth(•1))
RGBSTR+1(pattern(red(•1),"#")+","+pattern(green(•1),"#")+","+pattern(blue(•1),"#")
HTMLRGBSTR+1(radixstr("hex",red(•1))[-4,-3]+radixstr("hex",green(•1))[-4,-3]+radixstr("hex",blue(•1))[-4,-3]
HTMLRGB+1(rgb(
    int(256*(radix("hex",•1[1;2])*(255.997/255))),
    int(256*(radix("hex",•1[3;2])*(255.997/255))),
    int(256*(radix("hex",•1[5;2])*(255.997/255))) 
)
WHITE+0(rgb(65535,65535,65535)
BLACK+0(rgb(0,0,0)
GRAY+1(rgb((100-•1)*655,(100-•1)*655,(100-•1)*655)
LEFT+2(•1[1;•2]
MID+3(•1[•2;•3]
RIGHT+2(•1[-•2,-1]
TRIM+2(•1[1,-1-•2]
TRIMLEFT+2(•1[•2+1,-1]
CONNECT+3(?(•1<>"" and •3<>"",•1+•2+•3,•1+•3)
ARRAYFIRST+2(array(•1,1,•2)
ARRAYLAST+2(array(•1,arraysize(•1,•2),•2)
ARRAYTRIM+3(arrayrange(•1,1,arraysize(•1,•3)-•2,•3)
ARRAYLEFTTRIM+3(arrayrange(•1,•2+1,9999,•3)
FIRSTWORD+1(array(•1,1," ")
LASTWORD+1(array(•1,arraysize(•1," ")," ")
NTHWORD+2(array(•1,•2," ")
WORDCOUNT+1(extract(arraystrip(replacemultiple(•1,¶+":"+¬+":"+chr(10)," : : ",":")," ")," ",-1)
ONESPACE+1(arraystrip(•1," ")
ONEWHITESPACE+1(arraystrip(replace(•1,cr()," ",chr(10)," ",tab()," ")," ")
FIRSTLINE+1(array(•1,1,¶)
LASTLINE+1(array(•1,arraysize(•1,¶),¶)
NTHLINE+2(array(•1,•2,¶)
LINECOUNT+1(extract(•1,¶,-1)
FIXEDWIDTH+2((•1+rep(" ",•2))[1,•2]
FIXEDWIDTHRIGHT+2((rep(" ",•2)+•1)[-•2,-1]
PADZERO+2((rep("0",•2)+•1)[-•2,-1]
SUBFOLDER+2(folder(folderpath(•1)+replace(•2,":",info("foldersepchar")))
HOMESUBFOLDER+1(folder(info("userfolder")+"/"+replace(•1,":",info("foldersepchar")))
SUBPATH+2(folderpath(•1)+replace(•2,":",info("foldersepchar"))
DBSUBFOLDER+1(folder(folderpath(dbinfo("folder",""))+replace(•1,":",info("foldersepchar")))
PATHSEPARATOR+1(stripchar(•1,"//::")[1,1]
FILENAME+1(array(•1,arraysize(•1,pathseparator(•1)),pathseparator(•1))
FILEPATH+1(sandwich("",arrayrange(•1,1,arraysize(•1,pathseparator(•1))-1,pathseparator(•1)),pathseparator(•1))
FILEFOLDER+1(folder(filepath(•1))
FILEEXTENSION+1(?(•1 contains ".",array(•1,arraysize(•1,"."),"."),"")
URLPATH+1(arrayrange(•1,1,arraysize(•1,"/")-1,"/")+"/"
URLFILENAME+1(array(•1,arraysize(•1,"/"),"/")
FOLDERSEPCHAR+0(info("foldersepchar")
PATHEXISTS+1(folderexists(•1)
LISTTEXTFILES+1(listfiles(•1,"TEXT????")
LISTPANORAMAFILES+1(listfiles(•1,"ZEPD????")
HTMLBOLD+1("<b>"+•1+"</b>"
HTMLITALIC+1("<i>"+•1+"</i>"
DBFOLDER+0(dbinfo("folder","")
DBPATH+0(folderpath(dbinfo("folder",""))
DBNAME+0(info("databasename")
WINDOW+0(info("windowname")
TRUE+0(-1
FALSE+0(0
RANDOMLETTER+1(?(upper(•1)="U",chr(int(65+26*rnd())),?(upper(•1)="L",chr(int(97+26*rnd())),
			       ?(int(1+2*rnd())=1,chr(int(65+26*rnd())),chr(int(97+26*rnd())))))
STRIPHTMLTAGS+1(tagstrip(•1,"<",">")
SNIP+3(•1[1;•2-1]+?(•3=-1,"",•1[•2+•3,-1])
ARRAYREVERSELOOKUP+5(array(array(•5+•4+•3+•3+•1,1+arraysearch(•1+•3,•2+•3+"*",1,•4),•3),1,•4)
STATEABBREVIATIONS+0("AL:ALABAMA;AK:ALASKA;AS:AMERICAN SAMOA;AZ:ARIZONA;AR:ARKANSAS;CA:CALIFORNIA;CO:COLORADO;CT:CONNECTICUT;DE:DELAWARE;DC:DISTRICT OF COLUMBIA;FM:FEDERATED STATES OF MICRONESIA;FL:FLORIDA;GA:GEORGIA;GU:GUAM;HI:HAWAII;ID:IDAHO;IL:ILLINOIS;IN:INDIANA;IA:IOWA;KS:KANSAS;KY:KENTUCKY;LA:LOUISIANA;ME:MAINE;MH:MARSHALL ISLANDS;MD:MARYLAND;MA:MASSACHUSETTS;MI:MICHIGAN;MN:MINNESOTA;MS:MISSISSIPPI;MO:MISSOURI;MT:MONTANA;NE:NEBRASKA;NV:NEVADA;NH:NEW HAMPSHIRE;NJ:NEW JERSEY;NM:NEW MEXICO;NY:NEW YORK;NC:NORTH CAROLINA;ND:NORTH DAKOTA;MP:NORTHERN MARIANA ISLANDS;OH:OHIO;OK:OKLAHOMA;OR:OREGON;PW:PALAU;PA:PENNSYLVANIA;PR:PUERTO RICO;RI:RHODE ISLAND;SC:SOUTH CAROLINA;SD:SOUTH DAKOTA;TN:TENNESSEE;TX:TEXAS;UT:UTAH;VT:VERMONT;VI:VIRGIN ISLANDS;VA:VIRGINIA;WA:WASHINGTON;WV:WEST VIRGINIA;WI:WISCONSIN;WY:WYOMING"
STATENAME+1(upperword(arraylookup(stateAbbreviations(),upper(•1),";",":",""))
USPSSTREETSUFFIXES+0(binarytotext(fileload(bundleresourcepath("uspsstreetsuffixes.txt")))
USPSSECONDARYUNITS+0(binarytotext(fileload(bundleresourcepath("uspssecondaryunits.txt")))
STATELOOKUP+1(arraylookup(stateabbreviations(),upper(•1),";",":",•1)
RANGEMATCH+2(stripchar(•1,•2)=•1
RANGENOTMATCH+2(stripchar(•1,•2)<>•1
ARRAYDELETEVALUE+3(replace(•3+•1+•3,•3+•2+•3,•3)[length(•3)+1,-(length(•3)+1)]
ARRAYREPLACEVALUE+4(replace(•4+•1+•4,•4+•2+•4,•4+•3+•4)[length(•4)+1,-(length(•4)+1)]
QUOTED+1({"}+replace(•1,{"},{""})+{"}
ZBPATTERN+2(?(•1=0,"",pattern(•1,•2))
APPLESCRIPTSTRING+1({"}+replace(replace(•1,{\},{\\}),{"},{\"})+{"}
JSONSCRIPTSTRING+1({"}+replace(replace(•1,{\},{\\}),{"},{\"})+{"}
PERLSCRIPTSTRING+1({'}+replace(replace(•1,{\},{\\}),{'},{\'})+{'}
HTMLTABLECELLRAW+3(arrayrange(tagdata(tagdata(•1,"<tr","</tr>",•2),"<td","</td>",•3),2,9999,">")
HTMLTABLECELL+3(strip(tagstrip(arrayrange(tagdata(tagdata(•1,"<tr","</tr>",•2),"<td","</td>",•3),2,9999,">"),"<",">"))
HTMLTABLEROWRAW+2(arrayrange(tagdata(•1,"<tr","</tr>",•2),2,9999,">")
HTMLTABLEROW+3(tagstrip(tagarray(arrayrange(tagdata(•1,"<tr","</tr>",•2),2,9999,">"),"<td>","</td>",•3),"<",">")
HTMLTABLECELLEXISTS+3(tagdata(tagdata(•1,"<tr","</tr>",•2),"<td","</td>",•3)<>""
TEXTBEFORE+2(•1[1,-1+search(•1,•2)]
TEXTAFTER+2(?(•1 contains •2,•1[length(•2)+search(•1,•2),-1],•1)
HTMLTABLEHEIGHT+1(tagcount(•1,"<tr","</tr>")
HTMLTABLEWIDTH+1(tagcount(tagdata(•1,"<tr","</tr>",1),"<td","</td>")
CRTOVTAB+1(replace(•1,¶,chr(11))
VTABTOCR+1(replace(•1,chr(11),¶)
NUMSANDWICH+2(?(•1<>0,•1+•2,0)
CHARARRAY+2((•1)[•2;1]
BYTEARRAY+2(binaryvalue((•1)[•2;1])
WORDARRAY+2(binaryvalue((•1)[1+(•2-1)*2;2])
LONGWORDARRAY+2(binaryvalue((•1)[1+(•2-1)*4;4])
LONGLONGWORDARRAY+2(binaryvalue((•1)[1+(•2-1)*8;8])
CHUNKARRAY+3((•1)[1+(•2-1)*•3;•3]
YOKE+3(?(•1<>"" and •3<>"",•1+•2+•3,•1+•3)
OSX+0(-1
OS9+0(0
OSWINDOWS+0(0
POSIXPATH+1(replacemultiple(unixpath(•1), “\∆ ∆'∆"∆!∆#∆$∆%∆&∆(∆)∆*∆;∆<∆=∆>∆?∆[∆]∆`∆|∆~”,“\\∆\ ∆\'∆\"∆\!∆\#∆\$∆\%∆\&∆\(∆\)∆\*∆\;∆\<∆\=∆\>∆\?∆\[∆\]∆\`∆\|∆\~”,"∆")
UNIXSHELLPATH+1(unixpath(•1)
FULLPATH+1(?(•1 contains info("foldersepchar"),?(•1 beginswith info("foldersepchar"),dbpath()+•1[2,-1],•1),dbpath()+•1)
BIT+1(?(•1=64,2*hex("4000000000000000"),fix(2^(•1-1)))
GETBIT+2((bit(•2) and •1) <> 0
SETBIT+3((onescomplement(bit(•2)) and •1) + (bit(•2) and •3)
LOOKUPALLDOUBLE+7(arraymerge(lookupall(•1,•2,•3,•4,•6),lookupall(•1,•2,•3,•5,•6),•6,•7)
LOOKUPALLTRIPLE+8(arraymerge(arraymerge(lookupall(•1,•2,•3,•4,•7),lookupall(•1,•2,•3,•5,•7),•7,•8),lookupall(•1,•2,•3,•6,•7),•7,•8)
LOOKUPALLQUADRUPLE+9(arraymerge(arraymerge(arraymerge(lookupall(•1,•2,•3,•4,•8),lookupall(•1,•2,•3,•5,•8),•8,•9),lookupall(•1,•2,•3,•6,•8),•8,•9),lookupall(•1,•2,•3,•7,•8),•8,•9)
LOOKUPALLQUINTUPLET+10(arraymerge(arraymerge(arraymerge(arraymerge(lookupall(•1,•2,•3,•4,•9),lookupall(•1,•2,•3,•5,•9),•9,•:),lookupall(•1,•2,•3,•6,•9),•9,•:),lookupall(•1,•2,•3,•7,•9),•9,•:),lookupall(•1,•2,•3,•8,•9),•9,•:)
LOOKUPALLSEXTET+11(arraymerge(arraymerge(arraymerge(arraymerge(arraymerge(lookupall(•1,•2,•3,•4,•:),lookupall(•1,•2,•3,•5,•:),•:,•;),lookupall(•1,•2,•3,•6,•:),•:,•;),lookupall(•1,•2,•3,•7,•:),•:,•;),lookupall(•1,•2,•3,•8,•:),•:,•;),lookupall(•1,•2,•3,•9,•:),•:,•;)
LOOKUPALLSEPTUPLET+12(arraymerge(arraymerge(arraymerge(arraymerge(arraymerge(arraymerge(lookupall(•1,•2,•3,•4,•;),lookupall(•1,•2,•3,•5,•;),•;,•<),lookupall(•1,•2,•3,•6,•;),•;,•<),lookupall(•1,•2,•3,•7,•;),•;,•<),lookupall(•1,•2,•3,•8,•;),•;,•<),lookupall(•1,•2,•3,•9,•;),•;,•<),lookupall(•1,•2,•3,•:,•;),•;,•<)
LOOKUPALLOCTET+13(arraymerge(arraymerge(arraymerge(arraymerge(arraymerge(arraymerge(arraymerge(lookupall(•1,•2,•3,•4,•<),lookupall(•1,•2,•3,•5,•<),•<,•=),lookupall(•1,•2,•3,•6,•<),•<,•=),lookupall(•1,•2,•3,•7,•<),•<,•=),lookupall(•1,•2,•3,•8,•<),•<,•=),lookupall(•1,•2,•3,•9,•<),•<,•=),lookupall(•1,•2,•3,•:,•<),•<,•=),lookupall(•1,•2,•3,•;,•<),•<,•=)
XTAGVALUE+2(tagdata(•1,"<"+•2+">","</"+•2+">",1)
ARRAYCONTAINS+3(arraysearch(•1,•2,1,•3)>0
ARRAYCONTAINS+2(arraysearch(•1,•2)>0
ARRAYNOTCONTAINS+3((not arraycontains(•1,•2,•3))
ARRAYNOTCONTAINS+2(arraysearch(•1,•2)=0
DBCHECKOPEN+1(arraycontains(info("files"),•1,¶)
COMMASTR+1(pattern(•1,"#,")
LINESCONTAIN+2(arraycontains(•1,•2,¶)
LINESNOTCONTAIN+2((not arraycontains(•1,•2,¶))
LINESTRIP+1(arraystrip(•1,¶)
DEFAULTTEXT+2(?(•2="",•1,•2)
AFTER+2(tagdata(•1+chr(255)+chr(254)+chr(253),•2,chr(255)+chr(254)+chr(253),1)
BEFORE+2(tagdata(chr(255)+chr(254)+chr(253)+•1,chr(255)+chr(254)+chr(253),•2,1)
NTH+1(str(•1)+?(•1=0,"",?(abs((•1 MOD 100) - 12) < 2,"th","thstndrdthththththth"[(•1 MOD 10)*2+1;2]))
XTAG+2("<"+•1+">"+•2+"</"+•1+">"
BOOLSTR+1(?(•1=true(),"true","false")
EMPTYLINE+0(arraystrip(exportline(),chr(9))=""
EMPTYDATABASE+0(arraystrip(exportline(),chr(9))=""
REMOVEPREFIX+2(?(•1 beginswith •2,•1[length(•2)+1,-1],•1)
REMOVESUFFIX+2(?(•1 endswith •2,trim(•1,length(•2)),•1)
YEARVALUE+1(val(datepattern(•1,"YYYY"))
QUARTERVALUE+1(val(datepattern(•1,"QQ"))
MONTHVALUE+1(val(datepattern(•1,"MM"))
WEEKVALUE+1(val(datepattern(•1,"WW"))
DAYVALUE+1(val(datepattern(•1,"DD"))
RANGECONTAINS+2(stripchar(•1,•2)<>""
CONCATENATE+2(•1+•2
PLACES+2(array(str(•1),1,".")+"."+(array(str(•1),2,".")+rep("0",•2))[1,•2]
FILEEXISTSPATH+1(fileexists(•1)
PATHCONTENTS+1(listfiles(•1,"")
PATHCONTAINS+2(arraycontains(foldercontents(•1),•2,¶)
FOLDERCONTAINS+2(arraycontains(listfiles(•1,""),•2,¶)
FORMATPHONE+1(?(length(striptonum(•1))=10,
"("+striptonum(•1)[1,3]+") "+striptonum(•1)[4,6]+"-"+striptonum(•1)[7,10],
?(length(striptonum(•1))=7,striptonum(•1)[1,3]+"-"+striptonum(•1)[4,7],•1))
TCFRAMES+2((val(array(•1,1,":"))*60*60*•2)+(val(array(•1,2,":"))*60*•2)+(val(array(•1,3,":"))*•2)+(val(array(•1,4,":")))
TIMECODE+2(padzero(array(timepattern(int(•1/•2),"hh:mm:ss"),1,":"),2)+":"+
arrayrange(timepattern(int(•1/•2),"hh:mm:ss"),2,3,":")+":"+
padzero(str(•1 mod •2),2)
KCFRAMES+1(val(•1[-7,-4])*16+val(•1[-2,-1])
FEETANDFRAMES+1(padzero(str(int(•1/16)),4)+"+"+padzero(str(•1 mod 16),2)
TCDIFF+4(tcframes(•2,•3)-tcframes(•1,•3)-?(•4=1,1,0)
TCADD+3(timecode((tcframes(•1,•3)+•2),24)
OUTCODE+2(tcadd(•1,1,•2)
KCDIFF+2(kcframes(•2)-kcframes(•1)+1
KCADD+2(feetandframes(kcframes(•1)+•2)
KCOUTFROMLENGTH+2(feetandframes(kcframes(•1)+?(•2≥1,•2-1,•2+1))
TC24TO30+1(arrayrange(•1,1,3,":")+":"+getdictionaryvalue(Convert24To30Dict,arraylast(•1,":"))
TC30TO24+1(arrayrange(•1,1,3,":")+":"+getdictionaryvalue(Convert30To24Dict,arraylast(•1,":"))
TABARRAY+2(array(•1,•2,¬)
UNIXSHELLSTRING+1(ignore("",cache(“\∆ ∆'∆"∆!∆#∆$∆%∆&∆(∆)∆*∆;∆<∆=∆>∆?∆[∆]∆`∆|∆~”,"specialchars")+cache(“\\∆\ ∆\'∆\"∆\!∆\#∆\$∆\%∆\&∆\(∆\)∆\*∆\;∆\<∆\=∆\>∆\?∆\[∆\]∆\`∆\|∆\~”,"escapedchars"))+replacemultiple(str(•1)[1,1],specialchars[1,-3],escapedchars[1,-4],"∆")+replacemultiple(str(•1)[2,-1],specialchars,escapedchars,"∆")
PERLCONSTANT+1(?(expressiontype(•1)=0,{ '}+replacemultiple(str(•1),{\∆'},{\\∆\'},"∆")+{'},str(•1))
RUBYCONSTANT+1(?(expressiontype(•1)=0,{'}+replacemultiple(str(•1),{\∆'},{\\∆\'},"∆")+{'},str(•1))
PYTHONCONSTANT+1(?(expressiontype(•1)=0,{'''}+replacemultiple(str(•1),{'},{\'},"∆")+{'''},str(•1))
APPLESCRIPTCONSTANT+1(?(expressiontype(•1)=0,{"}+replace(replace(str(•1),{\},{\\}),{"},{\"})+{"},str(•1))
PHPCONSTANT+1(?(expressiontype(•1)=0,{'}+replacemultiple(str(•1),{'},{\'},"∆")+{'},str(•1))
CARDTYPE+1(stripchar(replacemultiple(•1[1,1],"3,4,5,6","American Express,Visa,MasterCard,Discover",","),"AZaz  ")
COMMATOCR+1(replace(•1,",",cr())
ARRAYTOPYTHONLIST+2("["+replace(arrayfilter(•1,•2,||| pythonconstant(import()) |||),•2,",")+"]"
SECSMINSHOURS+1(?(•1<60,pattern(•1,"# second~"),?(•1<3600,pattern(•1/60,"# minute~"),?((•1<3600*24),pattern(•1/3600,"# hour~"),pattern(•1/86400,"# day~"))))
BETWEEN+3(•1>=•2 and •1<=•3
NOTBETWEEN+3(•1<•2 or •1>•3
LIMIT+3(min(max(•1,•2),•3)
YEARS+1(int(float(•1)/float(365.25))
AGE+1(yearvalue(today()) - yearvalue(•1) - ?(monthvalue(•1) > 
monthvalue(today()) or monthvalue(•1)=monthvalue(today()) and 
dayvalue(•1) > dayvalue(today()),1,0)
YEARSBETWEEN+2(yearvalue(•2) - yearvalue(•1) - ?(monthvalue(•1) > 
monthvalue(•2) or monthvalue(•1)=monthvalue(•2) and 
dayvalue(•1) > dayvalue(•2),1,0)
TRIMSTART+2(•1[•2+1,-1]
SETRECTANGLEHEIGHT+2(rectanglesize(rtop(•1),rleft(•1),•2,rwidth(•1))
SETRECTANGLEWIDTH+2(rectanglesize(rtop(•1),rleft(•1),rheight(•1),•2)
SETRECTANGLESIZE+3(rectanglesize(rtop(•1),rleft(•1),•2,•3)
DEGREESTORADIANS+1(•1*pi()/180
RADIANSTODEGREES+1(•1*180/pi()
MAKEINTEGER+1(str(striptonum(places(rnd(),val(•1+2))))[2,min(•1,16)]
ARRAYITEMTRIM+4(arrayfilter(•1,•2,{import()[}+str(1+•3)+{,}+str(-1-•4)+{]})
ARRAYBOTH+3(arraystrip(arrayfilter(cache(arraysort(arraydeduplicate(arraystrip(•1,cache(•3,"thearraysepchar")),•3)+•3+arraydeduplicate(arraystrip(•2,•3),•3),•3),"tempboth"),•3,{?(import() = array(tempboth,seq()-1,thearraysepchar),import(),"")}),•3)
ARRAYDIFFERENCE+3(ignore("",cache(arraystrip(arrayfilter(cache(arraysort(arraydeduplicate(arraystrip(•1,cache(•3,"thearraysepchar")),•3)+•3+arraydeduplicate(arraystrip(•2,•3),•3),•3),"tempboth"),•3,{?(import() = array(tempboth,seq()-1,thearraysepchar),import(),"")}),•3),"comboarray"))+?(comboarray="",•1,arraystrip(arrayfilter(•1,•3,{?(arraycontains(comboarray,import(),thearraysepchar),"",import())}),•3))
COMMALIST+2(?(•1 contains •2,replace(arrayrange(•1,1,-2,•2)+" and "+array(•1,-1,•2),•2,", "),•1)
ARRAYITEMSANDWICH+4(ignore("",cache(•3,"arrayItemPrefix"),cache(•4,"arrayItemSuffix"))+arrayfilter(•1,•2,{sandwich(arrayItemPrefix,import(),arrayItemSuffix)})
MENUSEPARATOR+0("(-"+¶
STANDARDPANORAMAMENU+0("($Apple)"+¶
STANDARDHELPMENU+0("($Help)"+¶
STANDARDWIZARDSMENU+0(?(arraycontains(info("globalvariables"),"PanoramaWizardMenu",cr()),PanoramaWizardMenu,"")
RECTANGLEADJUST+5(rectangle(rtop(•1)+•2,rleft(•1)+•3,rbottom(•1)+•4,rright(•1)+•5)
RECTANGLEINSET+2(rectangleadjust(•1,•2,•2,-•2,-•2)
RECTANGLEOFFSET+3(rectangleadjust(•1,•2,•3,•2,•3)
RECTANGLECENTER+2(rectanglesize(rtop(•1)+rheight(•1)/2-rheight(•2)/2 , rleft(•1)+rwidth(•1)/2-rwidth(•2)/2 , rheight(•2), rwidth(•2))
CONSTANTVALUE+1(switch(datatype(•1),"Text",quoted(str(datavalue(•1))),"Binary",{decodebase64("}+encodebase64(datavalue(•1))+{")},str(datavalue(•1)))
MENUITEMS+1(replace(replace(•1,";",cr()),"¬",tab())
POINTSTR+1(str(v(•1))+","+str(h(•1))
TIMESTAMPSTR+0(batchreplace(superdatepattern(supernow(),"YYYY.MM.DD.","HH.MM.SS"),". 0.=.00.,. 1.=.01.,. 2.=.02.,. 3.=.03.,. 4.=.04.,. 5.=.05.,. 6.=.06.,. 7.=.07.,. 8.=.08.,. 9.=.09.",",","=")+"."+pattern(((info("tickcount") mod 60)*1000)/60,"###")
HOMEPATH+1(folderpath(info("userfolder"))+•1
APPLESCRIPT+1(call("_ScriptLib","AppleScriptFunction",•1)
PERL+1(call("_ScriptLib","PerlFunction",•1)
RUBY+1(call("_ScriptLib","RubyFunction",•1)
PYTHON+1(call("_ScriptLib","PythonFunction",•1)
PHP+1(call("_ScriptLib","PHPFunction",•1)
SHELLSCRIPT+1(call("_ScriptLib","ShellScriptFunction",•1)
RECTANGLEALIGN+3(rectangletweak(rectanglecenter(•1,•2),?(arraycontains(lower(•3),"top"," "),"y","miny"),0,?(arraycontains(lower( •3),"left"," "),"x","minx"),0,?(arraycontains(lower(•3),"bottom"," "),"y","maxy"),99999,?(arraycontains(lower(•3),"right"," "),"x","maxx"),99999,"minx",rleft(•1),"miny",rtop(•1),"maxx",rright(•1),"maxy",rbottom(•1))
REPLACEWORD+3(regexreplaceexact(•1,"\b"+regexliteral(lower(•2))+"\b",lower(•3),"\b"+regexliteral(upper(•2))+"\b",upper(•3),"\b"+regexliteral(upperword(•2))+"\b",upperword(•3))
REPLACEWORDEXACT+3(regexreplaceexact(•1,"\b"+regexliteral(•2)+"\b",•3)
CITY+1(ziplookup(val(•1),{City},"-")
STATE+1(ziplookup(val(•1),{State},"-")
COUNTY+1(ziplookup(val(•1),{County},"-")
ZIPLATITUDE+1(ziplookup(val(•1),{Latitude},"-")
ZIPLONGITUDE+1(ziplookup(val(•1),{Longitude},"-")
CITYZIPS+2(arraybuild(",","_USZipCodeLib",{pattern(Zip,"#####")},{City=}+quoted(upperword(•1))+{ and State=}+quoted(upper(•2)))
CITYZIP+2(superlookup("_USZipCodeLib",{City=}+quoted(upperword(•1))+{ and State=}+quoted(upper(•2)),{pattern(Zip,"#####")},"default","")
ZIPDISTANCE+2(latlongdistance(ziplatitude(•1),ziplongitude(•1),ziplatitude(•2),ziplongitude(•2))
COPYNEWERFILE+2(callwithin("_DiskLib","COPYNEWERFILE","function", •1,•2)
ARRAYCOLUMN+4(arrayfilter(•1,•3,{array(import(),}+•2+{,}+quoted(•4)+{)})
ARRAYMULTISORT+4(call("_CollectionsLib","ArrayMultiSort",•1,•2,•3,•4)
ARRAYNUMERICTOTAL+2(call("_CollectionsLib","ArrayNumericTotal",•1,•2)
ARRAYRANDOMIZE+2(call("_CollectionsLib","ArrayRandomize",•1,•2)
ARRAYTABLECEILING+5(call("_CollectionsLib","ArrayTable",•1,•2,•3,•4,•5,true())
ARRAYTABLEFLOOR+5(call("_CollectionsLib","ArrayTable",•1,•2,•3,•4,•5,false())
ARRAYUNPROPAGATE+2(call("_CollectionsLib","ArrayUnPropagate",•1,•2)
CARDEXPIREVALIDATE+2(call("_UtilityLib","CardExpireValidate",•1,•2)
CHECKEDMENUITEM+2(menuitem(•1,"STATE",?(•2,"ON","OFF"))
PLURALPATTERN+2(call("_TextLib","PluralPattern",•1,•2,"are/is,Are/Is,ARE/IS,have/has/Have/Has,HAVE/HAS,people/person,People/Person,PEOPLE/PERSON")
CUSTOMPLURALPATTERN+3(call("_TextLib","PluralPattern",•1,•2,•3)
COUNTSUMMARIES+1(call("_DatabaseLib","COUNTSUMMARIES",•1)
DOUBLECLICK+0(info("modifiers") contains "double"
SHIFTCLICK+0(info("modifiers") contains "shift"
OPTIONCLICK+0(info("modifiers") contains "option"
ENCLOSINGPATH+1(?(•1 contains ":",arraytrim(removesuffix(•1,":"),1,":"),arraytrim(removesuffix(•1,"/"),1,"/"))
ENCLOSINGFOLDER+1(?(•1 contains ":",arraylast(enclosingpath(•1),":"),arraylast(enclosingpath(•1),"/"))
EXTENSIONTYPE+1(filetypecreator(•1)[1,4]
FIELDALIGNMENT+2(getdictionaryvalue(getfieldproperties(•1,•2),"ALIGN")
FIELDFORMULA+2(getdictionaryvalue(getfieldproperties(•1,•2),"FORMULA")
FIELDNUMBER+2(catcherror(0,getdictionaryvalue(getfieldproperties(•1,•2),"ID"))
FIELDPATTERN+2(getdictionaryvalue(getfieldproperties(•1,•2),"OUTPUTPATTERN")
FIELDWIDTH+2(getdictionaryvalue(getfieldproperties(•1,•2),"WIDTH")
FOLDERCONTENTS+1(?(length(folder(•1))>0,listfiles(folder(•1),""),"")
FOLDERCOUNT+1(val(getdictionaryvalue(call("_DiskLib","FOLDERINFO",•1),"COUNT"))
FOLDERSIZE+1(val(getdictionaryvalue(call("_DiskLib","FOLDERINFO",•1),"SIZE"))
GETAUTONUMBER+0(dbinfo("autonumber","")
GETWEBCOLOR+2(call("_FormLib","GetWebColor",•1,•2)
GRABFIELDTYPE+2(switch(getdictionaryvalue(getfieldproperties(•1,•2),"TYPE"),"Date",4,"Float",5,"Integer",6,"Binary",11,0)
LINESORT+1(arraysort(•1,cr())
MAKENUMBEREDARRAY+3(ignore("",cache(•2-1,"mnastart"))+exportdataarray(generatedataarray(•3+1-•2,{mnastart +seq()}),•1)
NOACTIONMENU+0(""
NOINSTRUMENTATIONMENU+0(""
NOWIZARDMENU+0(""
OBSCUREDIGITS+2(characterfilter(•1,{?(stripchar(import(),"09")=import(),"X",import())})[1,-•2-1]+•1[-•2,-1]
RANDOMARRAYELEMENT+2(array(•1,randominteger(1,arraysize(•1,•2)),•2)
RANDOMWORD+1(randomarrayelement(•1," ")
RANDOMLINE+1(randomarrayelement(•1,cr())
TEMPFOLDER+0(info("tempfolder")
FIELDTYPES+1(call("_UtilityLib","FIELDTYPES",•1)
BESTFITRECTANGLE+2(call("_FormLib","BESTFITRECTANGLE",•1,•2)
MIXEDUPPERWORD+1(arrayfilter(•1," ",{?(import()=lower(import()),upperword(import()),import())})
HIDDENFIELDS+0(info("hiddenfields")
DEVBUILD+0(dbinfo("folder","_ProvueLib") notcontains ".app/Contents/Resources"
SHORTSTANDARDVIEWMENU+0(?(devbuild(),standardviewmenu(),arrayrange(standardviewmenu(),1,4,cr())+cr())
URLENCODE+1(percentescape(•1," ")
URLDECODE+1(replace(percentunescape(replace(•1,"%25","\\\PERCENT///")),"\\\PERCENT///","%")
WEBLINK+2(?(updatingwindow()=false(),{<a href="}+urlencode(•1)+{">}+?(•2<>"",•2,•1)+{</a>},?(•2<>"",•2,•1))
WEBLINKNEWWINDOW+2(?(updatingwindow()=false(),{<a href="}+•1+{" target="_blank">}+?(•2<>"",•2,•1)+{</a>},?(•2<>"",•2,•1))
UNCLOAKEDDATABASENAME+1(replace(?(•1<>"",•1,info("databasename")),"_"+catcherror("",«_dbSharingVirtualAccount»)+"_","")
UNCLOAKEDDATABASENAME+0(replace(info("databasename"),"_"+info("liait")+"_","")
CLOAKEDDATABASENAME+1(replace(?(thecloakedname<>"",thecloakedname,info("databasename")),"_"+catcherror("",«_dbSharingVirtualAccount»)+"_","")
CLOAKEDDATABASENAME+0("_"+info("liait")+"_"+info("databasename")
CGILINK+3(weblink(catcherror("","http://"+datavalue("cgiServerDomain"))+"/cgi-bin/Panoramax.cgi?"+uncloakeddatabasename(•1)+"~"+•2,•3)
CGILINKNEWWINDOW+3(weblinknewwindow(catcherror("",datavalue("cgiServerDomain"))+"/cgi-bin/Panorama.cgi?"+uncloakeddatabasename(•1)+"~"+•2,•3)
CGINAVLINK+2(weblink(catcherror("",datavalue("cgiServerDomain"))+"/cgi-bin/Panorama.cgi?"+uncloakeddatabasename()+"~"+•1+"~="+str(info("serverrecordid")),•2)
CGINAVLINKNEWWINDOW+2(weblinknewwindow(catcherror("",datavalue("cgiServerDomain"))+"/cgi-bin/Panorama.cgi?"+uncloakeddatabasename()+"~"+•1+"~="+str(info("serverrecordid")),•2)
WEBFORMLINK+4(cgilink(•1,"Form~"+•2+sandwich("~",•3,""),?(•4<>"",•4,•2))
WEBFORMLINKNEWWINDOW+4(cgilinknewwindow(•1,"Form~"+•2+sandwich("~",•3,""),?(•4<>"",•4,•2))
HTMLENCODE+1(/* iso8859-1 generator */ characterfilter(•1,|||switch(import(), {‘},{'}, {’},{'}, {”},{"}, {“},{"}, {&},{&amp;}, { },{&nbsp;}, {¡},{&#161;}, {¢},{&#162;}, {£},{&#163;}, {€},{&#164;}, {¥},{&#165;}, {|},{&#124;}, {§},{&#167;}, {¨},{&#168;}, {©},{&copy;}, {ª},{&#170;}, {«},{&#171;}, {¬},{&#172;}, {–},{&#173;}, {®},{&reg;}, {¯},{&#175;}, {˚},{&#176;}, {±},{&#177;}, {´},{&#180;}, {µ},{&#181;}, {¶},{&#182;}, {•},{&#183;}, {¸},{&#184;}, {º},{&#186;}, {»},{&#187;}, {¿},{&#191;}, {À},{&Agrave;}, {Á},{&Aacute;}, {Â},{&Acirc;}, {Ã},{&Atilde;}, {Ä},{&Auml;}, {Å},{&Aring;}, {Æ},{&AElig;}, {Ç},{&Ccedil;}, {È},{&Egrave;}, {É},{&Eacute;}, {Ê},{&Ecirc;}, {Ë},{&Euml;}, {Ì},{&Igrave;}, {Í},{&Iacute;}, {Î},{&Icirc;}, {Ï},{&Iuml;}, {Ñ},{&Ntilde;}, {Ò},{&Ograve;}, {Ó},{&Oacute;}, {Ô},{&Ocirc;}, {Õ},{&Otilde;}, {Ö},{&Ouml;}, {Ù},{&Ugrave;}, {Ú},{&Uacute;}, {Û},{&Ucirc;}, {Ü},{&Uuml;}, {ß},{&zslig;}, {à},{&agrave;}, {á},{&aacute;}, {â},{&acirc;}, {ã},{&atilde;}, {ä},{&auml;}, {å},{&aring;}, {æ},{&aelig;}, {ç},{&ccedil;}, {è},{&egrave;}, {é},{&eacute;}, {ê},{&ecirc;}, {ë},{&euml;}, {ì},{&igrave;}, {í},{&iacute;}, {î},{&icirc;}, {ï},{&iuml;}, {ñ},{&ntilde;}, {ò},{&ograve;}, {ó},{&oacute;}, {ô},{&ocirc;}, {õ},{&otilde;}, {ö},{&ouml;}, {÷},{&#247;}, {ù},{&ugrave;}, {ú},{&uacute;}, {û},{&ucirc;}, {ü},{&uuml;}, {ÿ},{&yuml;}, import())|||)
HTMLDECODE+1(/* iso8859-1 generator */ batchreplace(•1,|||&lt;_<~&gt;_>~&quot;_"~&#34;_&~&amp;_&~&#160;_ ~&nbsp;_ ~&#161;_¡~&#162;_¢~&#163;_£~&#164;_€~&#165;_¥~&#124;_|~&#167;_§~&#168;_¨~&#169;_©~&copy;_©~&#170;_ª~&#171;_«~&#172;_¬~&#173;_–~&#174;_®~&reg;_®~&#175;_¯~&#176;_˚~&#177;_±~&#178;_~&#179;_~&#180;_´~&#181;_µ~&#182;_¶~&#183;_•~&#184;_¸~&#185;_~&#186;_º~&#187;_»~&#188;_~&#189;_~&#190;_~&#191;_¿~&#192;_À~&Agrave;_À~&#193;_Á~&Aacute;_Á~&#194;_Â~&Acirc;_Â~&#195;_Ã~&Atilde;_Ã~&#196;_Ä~&Auml;_Ä~&#197;_Å~&Aring;_Å~&#198;_Æ~&AElig;_Æ~&#199;_Ç~&Ccedil;_Ç~&#200;_È~&Egrave;_È~&#201;_É~&Eacute;_É~&#202;_Ê~&Ecirc;_Ê~&#203;_Ë~&Euml;_Ë~&#204;_Ì~&Igrave;_Ì~&#205;_Í~&Iacute;_Í~&#206;_Î~&Icirc;_Î~&#207;_Ï~&Iuml;_Ï~&#208;_~&#209;_Ñ~&Ntilde;_Ñ~&#210;_Ò~&Ograve;_Ò~&#211;_Ó~&Oacute;_Ó~&#212;_Ô~&Ocirc;_Ô~&#213;_Õ~&Otilde;_Õ~&#214;_Ö~&Ouml;_Ö~&#215;_~&#216;_~&#217;_Ù~&Ugrave;_Ù~&#218;_Ú~&Uacute;_Ú~&#219;_Û~&Ucirc;_Û~&#220;_Ü~&Uuml;_Ü~&#221;_~&Yacute;_~&#222;_~&#223;_ß~&zslig;_ß~&#224;_à~&agrave;_à~&#225;_á~&aacute;_á~&#226;_â~&acirc;_â~&#227;_ã~&atilde;_ã~&#228;_ä~&auml;_ä~&#229;_å~&aring;_å~&#230;_æ~&aelig;_æ~&#231;_ç~&ccedil;_ç~&#232;_è~&egrave;_è~&#233;_é~&eacute;_é~&#234;_ê~&ecirc;_ê~&#235;_ë~&euml;_ë~&#236;_ì~&igrave;_ì~&#237;_í~&iacute;_í~&#238;_î~&icirc;_î~&#239;_ï~&iuml;_ï~&#240;_~&#241;_ñ~&ntilde;_ñ~&#242;_ò~&ograve;_ò~&#243;_ó~&oacute;_ó~&#244;_ô~&ocirc;_ô~&#245;_õ~&otilde;_õ~&#246;_ö~&ouml;_ö~&#247;_÷~&#248;_~&#249;_ù~&ugrave;_ù~&#250;_ú~&uacute;_ú~&#251;_û~&ucirc;_û~&#252;_ü~&uuml;_ü~&#253;_~&yacute;_~&#254;_~&#255;_ÿ~&yuml;_ÿ|||,{~},{_})
DBCONSTRUCTORMENU+1(arrayfilter(arraysort(arraystrip(arrayfilter(dbinfo("procedures",•1),cr(),{?(import() beginswith "📐",import(),"")}),cr()),cr()),cr(),replace(|||tab()+import()[3,-1]+tab()+"{farcall “THEDB”,"+quoted(import())+"}"|||,"THEDB",•1))
STANDARDCONSTRUCTGRAPHICSMENU+0(sandwich(menu("Construct"),yoke(dbconstructormenu("_FormConstructorLib"),cr()+menuseparator(),dbconstructormenu(info("databasename"))),cr())
STANDARDINSTRUMENTATIONMENU+0(?(catcherror("",getpreferencevalue("PXDebugLogsPanel"))="","",ignore("",cache(defaulttext("<nil>",catcherror("",callwithin("_ProVUELib","debugLogPreferencePanel","logOutputApp"))),"consoleOutputApp"),cache(catcherror("",windowinfo("","procedure")),"windowProcedure"))+menu("🔬")+menuitem("Open Instrumentation Panel","CODE",{farcall "_ProvueLib","OPENPREFERENCESWINDOW","Instrumentation"})+menuseparator()+menuitem("Instrumentation Note…","CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","debugNote"})+menuseparator()+?(windowProcedure="","",menuitem("Enable Coverage (Current Procedure)","STATE",zlogging(info("databasename"),windowProcedure),"CODE",{farcallwithin "_ProvueLib",debugLogPreferencePanel,procedureCoverageToggle})+menuitem("Enable Coverage (All Procedures)","STATE",arrayfirst(catcherror("",globaldictionaryvalue("_zlogging",info("databasename"))),",")="--- ALL ---","CODE",{farcallwithin "_ProvueLib",debugLogPreferencePanel,allProcedureCoverageToggle})+menuseparator())+?(consoleOutputApp="<nil>",menuitem("Open Console.app","CODE",{farcallwithin "_ProvueLib",debugLogPreferencePanel,openAndEnableConsole}),menuitem("Send Log to "+ consoleOutputApp,"STATE",booleanvalue(catcherror("",globaldictionaryvalue("_zlog_options","console"))),"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","logToConsole"})+menuseparator()+menuitem("Bring "+consoleOutputApp+" to Front","INDENT",1,"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","clickLogOuputApp"}))+menuseparator()+menuitem("Save Log to File","STATE",booleanvalue(catcherror("",globaldictionaryvalue("_zlog_options","enablelogfile"))),"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","enableLogFile"})+menuseparator()+menuitem("Reveal Log in Finder","INDENT",1,"CODE",{revealinfinder callwithin("_PanoramaLib","ZLOG","getzlogpath")})+menuitem("Copy Log to Clipboard","INDENT",1,"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","debugLogGearClipLog"})+menuitem("Open Log in BBEdit","INDENT",1,"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","debugLogGearOpenInBBEdit"})+menuseparator()+menuitem("Archive Log","INDENT",1,"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","debugLogGearArchiveLog"})+menuitem("Archive Log…","INDENT",1,"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","debugLogGearArchiveDialogLog"})+menuitem("Clear Log","INDENT",1,"CODE",{farcallwithin "_ProvueLib","debugLogPreferencePanel","debugLogGearClearLog"})+"")
EMPTYCELL+1(sizeof(•1)=0
NOT+1((not •1)
RICHTEXTDATA+1(replace(•1,"<","<char:0x3c>")
CHANNELACTIVEMODULE+1(call("_ChannelsLib","ChannelActiveModule",•1)
CHANNELINFORMATION+3(call("_ChannelsLib","ChannelInformation", •1,•2,•3)
CHANNELMODULES+1(call("_ChannelsLib","ChannelModules", •1)
CHANNELPATH+2(call("_ChannelsLib","ChannelPath", •1,•2)
CHANNELTYPES+0(call("_ChannelsLib","ChannelTypes")
INFINITY+0(1/0
LFTOCR+1(replace(replace(•1,crlf(),cr()),lf(),cr())
CRTOLF+1(replace(replace(•1,crlf(),lf()),cr(),lf())
MACTOUTF8+1(•1
UTF8TOMAC+1(•1
REPLACEFIRST+3(ignore("",cache("{{{{{{{{{{{{{","OPEN")+cache("}}}}}}}}}}}}}}","CLOSE")+cache(chr(1),"PREFIX")+cache(replace(PREFIX+•1,•2,OPEN+•2+CLOSE)+OPEN+CLOSE,"TEMP"))+before(TEMP,OPEN)[2,-1]+•3+replace(replace(after(TEMP,CLOSE),OPEN,""),CLOSE,"")
REGEXREPLACEFIRST+3(ignore("",cache("{{{{{{{{{{{{{","OPEN")+cache("}}}}}}}}}}}}}}","CLOSE")+cache(chr(1),"PREFIX")+cache(regexreplace(PREFIX+•1,•2,OPEN+"$0"+CLOSE)+OPEN+CLOSE,"TEMP"))+before(TEMP,OPEN)[2,-1]+replace(•3,"$0",tagdata(TEMP,OPEN,CLOSE,1))+replace(replace(after(TEMP,CLOSE),OPEN,""),CLOSE,"")
REGEXREPLACEFIRSTEXACT+3(ignore("",cache("{{{{{{{{{{{{{","OPEN")+cache("}}}}}}}}}}}}}}","CLOSE")+cache(chr(1),"PREFIX")+cache(regexreplaceexact(PREFIX+•1,•2,OPEN+"$0"+CLOSE)+OPEN+CLOSE,"TEMP"))+before(TEMP,OPEN)[2,-1]+replace(•3,"$0",tagdata(TEMP,OPEN,CLOSE,1))+replace(replace(after(TEMP,CLOSE),OPEN,""),CLOSE,"")
NSRECT+4(rectanglesize(•2,•1,•4,•3)
NSRECTSTR+1(str(rleft(•1))+","+str(rtop(•1))+","+str(rwidth(•1))+","+str(rheight(•1))
POINTSVAL+1(callwithin("_FormConstructorLib", "CONSTRUCTFORMDATAEDITORS", "getPoints",•1)
LINEITEMARRAY+2(replace(strip("!"+arrayfilter(arraystrip(arrayfilter(dbinfo("lineitemfields",""),cr(),{?((import() regexmatchexact "^"+regexliteral(}+replace(quoted(tokenname(•1)),"Ω","")+{)+"[0-9]+$"),import(),"")}),cr()),cr(),{exportcell(import(),false())}))[2,-1],cr(),•2)
BONJOURSERVERSENABLED+0(catcherror("x",getpreferencevalue("PXIncludeBonjourServers"))="x"
PANORAMAXSERVERS+0(yoke(arrayhack(bonjour("_panxserver._tcp"),cr(),"__PRIVATE__"+catcherror("",getpreferencevalue("PXPanoramaLocalServerName")),"="+sandwich("",catcherror("",getpreferencevalue("PXPanoramaLocalServerName")),tab()+"http:/"+"/localhost:"+catcherror("",getpreferencevalue("PXPanoramaLocalServerPort")))),cr(),catcherror("",«_EnterpriseRemoteHostArray»))
PANORAMAXSERVERURL+1(ignore("",cache(arraylookup(panoramaxservers(),•1,cr(),tab(),""),"rawserverurl"))+?(rawserverurl regexmatch "\.local\.:[0-9]+$","http://","")+rawserverurl
ARCHIVECONTENTS+1(callwithin("_DiskLib","UNCOMPRESS","archivecontent",•1)
IMAGEINFO+1(dictionaryfromarray(arrayfilter(after(lftocr(arrayhack(shellscript("sips -g all "+unixshellstring(•1)),"ΩΩΩ","SHELL ERROR:","↩")),cr()),cr(),{strip(before(import(),": "))+tab()+strip(after(import(),": "))}))
IMAGEDIMENSIONS+1(ignore(hextobinary(""),cache(imageinfo(•1),"ixInfo"))+point(val(getdictionaryvalue(ixInfo,"pixelHeight")),val(getdictionaryvalue(ixInfo,"pixelWidth")))
MAPURL+5("http://maps.google.com/maps?q="+arraystrip(replace(•1+" "+•2+" "+•3+" "+•4," ","+"),"+")
MAPURL+4("http://maps.google.com/maps?q="+arraystrip(replace(•1+" "+•2+" "+•3+" "+•4," ","+"),"+")
SPECIALKEY+1(switchmatch(stripchar(lower(•1),"az09"),"uparrow",chr(0xF700),"downarrow",chr(0xF701),"leftarrow",chr(0xF702),"rightarrow",chr(0xF703),"f1",chr(0xF704),"f2",chr(0xF705),"f3",chr(0xF706),"f4",chr(0xF707),"f5",chr(0xF708),"f6",chr(0xF709),"f7",chr(0xF70A),"f8",chr(0xF70B),"f9",chr(0xF70C),"f9",chr(0xF70D),"f10",chr(0xF70B),"f11",chr(0xF70C),"f12",chr(0xF70D),"home",chr(0xF729),"pageup",chr(0xF72C),"pagedown",chr(0xF72D),error("unknown key"))
WEBFORMITEMVALUE+1(getdictionaryvalue(catcherror("",datavalue("cgiPostParameters")),•1)
SERVERVARIABLE+2(callwithin("_EnterpriseClientLib","clientFUNCTIONS","servervariable",•1,•2)
SERVERVARIABLE+1(callwithin("_EnterpriseClientLib","clientFUNCTIONS","servervariable",•1)
SERVERVARIABLENAMES+1(callwithin("_EnterpriseClientLib","clientFUNCTIONS","servervariablenames",•1)
SERVERVARIABLENAMES+0(callwithin("_EnterpriseClientLib","clientFUNCTIONS","servervariablenames")
SERVERVARIABLES+1(callwithin("_EnterpriseClientLib","clientFUNCTIONS","servervariables",•1)
SERVERVARIABLES+0(callwithin("_EnterpriseClientLib","clientFUNCTIONS","servervariables")
ADJUSTSERVERVARIABLE+3(call("_EnterpriseClientLib","ADJUSTSERVERVARIABLE",•1,•2,•3)
ADJUSTSERVERVALUE+2(call("_EnterpriseClientLib","ADJUSTSERVERVARIABLE",•1,•2)
FORMULAFIELDS+2(arrayboth(formulaidentifiers(•2),dbinfo("fields",•1),cr())
FORMULAFIELDS+1(arrayboth(formulaidentifiers(•1),dbinfo("fields",""),cr())
FORMULAVARIABLES+2(arraydifference(formulaidentifiers(•2),dbinfo("fields",•1),cr())
FORMULAVARIABLES+1(arraydifference(formulaidentifiers(•1),dbinfo("fields",""),cr())
WEBTEXT+1(replace(htmlencode(•1),"<","&lt;",">","&gt;",cr(),"<br>",lf(),"<br>")
WEBTAGORTEXT+1(replace(?(str(•1) match "<*>" or str(•1) contains "</" or str(•1) contains "<img",str(•1),webtext(str(•1))),"<>","")
SERVERRUNNING+0(info("httprequestinprogress")
SERVERNAME+1(dbinfo("host",•1)
SERVERDATABASENAME+1(dbinfo("SERVERDATABASENAME",•1)
GETWEBTEMPLATE+2(callwithin("_EnterpriseWebPublishLib","GETWEBTEMPLATE","getTemplate",•1,•2)
GETWEBTEMPLATE+1(callwithin("_EnterpriseWebPublishLib","GETWEBTEMPLATE","getTemplate","",•1)
GETWEBTEMPLATETEXT+2(getdictionaryvalue(getwebtemplate(•1,•2),"HTML")
GETWEBTEMPLATETEXT+1(getdictionaryvalue(getwebtemplate("",•1),"HTML")
LISTWEBTEMPLATES+1(callwithin("_EnterpriseWebPublishLib","LISTWEBTEMPLATES","listTemplates",•1)
RENDERWEBFORM+3(callwithin("_EnterpriseWebPublishLib","RENDERWEBFORM","render",•1,•2,•3)
RENDERWEBFORM+2(callwithin("_EnterpriseWebPublishLib","RENDERWEBFORM","render",•1,•2,"")
WEBFORMITEMNAMES+0(listdictionarykeys(catcherror("",datavalue("cgiPostParameters")))
WEBFORMALLITEMS+0(listdictionarykeys(catcherror("",datavalue("cgiPostParameters")))
WEBFORMITEMS+0(arraystrip(arrayfilter(webformitemnames(),cr(),|||?(import() match "_*_","",import())|||),cr())
WEBFORMVISIBLEITEMS+0(replace(webformitemvalue("_VISIBLEFIELDS_"),",",cr())
WEBFORMHIDDENITEMS+0(arraydifference(webformitems(),webformvisibleitems(),cr())
WEBFORMERRORS+1(callwithin("_EnterpriseWebPublishLib","WEBFORMITEMCHECK","WEBFORMERRORS",•1)
LISTWEBTABLES+1(callwithin("_EnterpriseWebPublishLib","LISTWEBTABLES","WEBTABLES",•1)
LISTWEBTABLES+0(callwithin("_EnterpriseWebPublishLib","LISTWEBTABLES","WEBTABLES","")
GETWEBTABLETEMPLATE+2(callwithin("_EnterpriseWebPublishLib","GETWEBTABLETEMPLATE","CONVERT",•1,•2)
RENDERWEBTABLE+1(callwithin("_EnterpriseWebPublishLib","RENDERWEBTABLE","RENDER",•1)
WEBFORMNAME+0(webformitemvalue("_FORMNAME_")
WEBFORMITEMERROR+1(getdictionaryvalue(catcherror("",datavalue("cgiFormItemErrors")),•1)
DBSERVERDOMAIN+0(?(info("runningonserver"),"http://"+catcherror("",datavalue("cgiServerDomain")),panoramaxserverurl(dbinfo("host","")))
WEBFORMITEMBANG+1(?(webformitemerror(•1)="","",defaulttext("!",catcherror("",datavalue("cgiFormItemBang"))))
WEBTHISRECORDKEY+1(callwithin("_EnterpriseWebPublishLib","WEBTHISRECORDKEY","FUNCTION",•1)
WEBFORMMISSINGFIELDS+1(callwithin("_EnterpriseWebPublishLib","WEBFORMTODATABASE","MISSINGFIELDS",•1)
WEBFONTSUBSTITUTES+0(callwithin("_FormLib","WEBFONTSUBSTITUTES","fonts")
GETUPLOADEDDATA+1(callwithin("_EnterpriseClientLib","UPLOADDATATOSERVER","GETUPLOADEDDATA",•1)
STRIPACCENTS+1(stripdiacriticals(•1)
STRAIGHTQUOTES+1(replace(•1,{’},{'},{‘},{'},{“},{"},{”},{"})
SHAREDDATABASEBOOKMARKEDPATH+2(callwithin("_EnterpriseClientLib","BOOKMARKSHAREDDATABASE","path",•1,•2)
SHAREDDATABASEBOOKMARKEDPATH+1(callwithin("_EnterpriseClientLib","BOOKMARKSHAREDDATABASE","path",•1)
SHAREDDATABASEBOOKMARKEDPATH+0(callwithin("_EnterpriseClientLib","BOOKMARKSHAREDDATABASE","path")
SHAREDUSERS+1(callwithin("_EnterpriseClientLib","clientFUNCTIONS","sharedusers",•1)
SHAREDUSERS+0(callwithin("_EnterpriseClientLib","clientFUNCTIONS","sharedusers","")
SERVERLOOKUP+6(callwithin("_EnterpriseClientLib","clientFUNCTIONS","serverlookup", •1,•2,•3,•4,•5,•6)
SERVERLOOKUP+5(callwithin("_EnterpriseClientLib","clientFUNCTIONS","serverlookup", •1,•2,•3,•4,•5)
SERVERLOOKUP+4(callwithin("_EnterpriseClientLib","clientFUNCTIONS","serverlookup", •1,•2,•3,•4)
SERVERLOOKUPALL+5(callwithin("_EnterpriseClientLib","clientFUNCTIONS","serverlookupall",•1,•2,•3,•4,•5)
SERVERSUPERLOOKUP+3(callwithin("_EnterpriseClientLib","clientFUNCTIONS","serversuperlookup",•1,•2,•3)
WEBIMAGEDISPLAY+2(?(updatingwindow(),•2,•1)
LOREMIPSUM+1(arrayrange(cache("Lorem ipsum dolor sit amet, consectetur adipiscing elit, sed do eiusmod tempor incididunt ut labore et dolore magna aliqua. Ut enim ad minim veniam, quis nostrud exercitation ullamco laboris nisi ut aliquip ex ea commodo consequat. Duis aute irure dolor in reprehenderit in voluptate velit esse cillum dolore eu fugiat nulla pariatur. Excepteur sint occaecat cupidatat non proident, sunt in culpa qui officia deserunt mollit anim id est laborum. At vero eos et accusamus et iusto odio dignissimos ducimus qui blanditiis praesentium voluptatum deleniti atque corrupti quos dolores et quas molestias excepturi sint occaecati cupiditate non provident, similique sunt in culpa qui officia deserunt mollitia animi, id est laborum et dolorum fuga. Et harum quidem rerum facilis est et expedita distinctio. Nam libero tempore, cum soluta nobis est eligendi optio cumque nihil impedit quo minus id quod maxime placeat facere possimus, omnis voluptas assumenda est, omnis dolor repellendus. Temporibus autem quibusdam et aut officiis debitis aut rerum necessitatibus saepe eveniet ut et voluptates repudiandae sint et molestiae non recusandae. Itaque earum rerum hic tenetur a sapiente delectus, ut aut reiciendis voluptatibus maiores alias consequatur aut perferendis doloribus asperiores repellat. ","_loremipsum"),1,4,". ")+"."+?(•1=1,"",arraystrip(replace(arrayfilter(" "+rep(chr(1),•1-2),chr(1),{¶+¶+arrayrange(arrayrandomize(arrayrange(_loremipsum[1,-2],2,-1,". "),". "),1,randominteger(1,5),". ")+"."}),¶+¶+". ",¶+¶),".")+".")
TITLECASE+1(?(arraysize(•1," ")<3,upperword(•1),upperword(arrayfirst(•1," "))+" "+arrayfilter(arrayrange(upperword(•1),2,-2," ")," ",{?(arraycontains(upperword("a an the and but for nor or so yet of at to in for on by but up out off as with from into upon like over plus down near"),import()," "),lower(import()),import())})+" "+upperword(arraylast(•1," ")))
TIMEREXISTS+1(length(catcherror("",timerinfo(•1)))>0
LOCALPANORAMAXSERVERNAME+0(catcherror(defaulttext(info("user"),before(info("computername"),"’"))+{'s Panorama X Server},getpreferencevalue("PXPanoramaServerName"))
LOCALPANORAMAXSERVERS+0(arrayfilter(bonjour("_panxserver._tcp"),cr(),{tabarray(import(),1)})
LOCALPANORAMAXSERVERISRUNNING+0(arraycontains(cache(localpanoramaxservers(),"_servernames"),cache(localpanoramaxservername(),"_servername"),cr()) or arraycontains(_servernames,"__PRIVATE__"+_servername,cr())
DBSHARED+0(dbinfo("shared","")
REMOTEPANORAMAXSERVERS+0(arrayfilter(catcherror("",«_EnterpriseRemoteHostArray»),cr(),{tabarray(import(),1)})
LABELIZEFORMULA+1(labelizepattern(croptext(•1,40),formulavalue(•1),"«label» --> «value»"+cr()+"=== «label» ============"+cr()+"«value»"+cr()+"=== END OF «label» ============")
LABELIZEFORMULA+2(labelizepattern(croptext(•1,40),formulavalue(•1),•2)
LABELIZEINFO+1(labelizepattern({info("}+•1+{")},formulavalue({info("}+•1+{")}),"«label» --> «value»"+cr()+"=== «label» ============"+cr()+"«value»"+cr()+"=== END OF «label» ============")
LABELIZEINFO+2(labelizepattern({info("}+•1+{")},formulavalue({info("}+•1+{")}),•2)
RELATEDRECORDID+1(related({info("serverrecordid")},•1)
CHECKSERVERCONNECTION+1(callwithin("_EnterpriseClientLib","CHECKSERVERCONNECTION","function",•1)
RECORDISLOCKED+0(dbinfo("recordlockid","")=info("serverrecordid")
PROVUESERVERISUP+0(call("_ProvueLib","PROVUESERVERISUP")